1 files changed, 87 insertions, 0 deletions
diff --git a/home/mon_data.asm b/home/mon_data.asm
new file mode 100755
index 00000000..c18bfd20
--- /dev/null
+++ b/home/mon_data.asm
@@ -0,0 +1,87 @@
+Unreferenced_GetNthMove::
+	ld hl, wd149
+	ld c, a
+	ld b, 0
+	add hl, bc
+	ld a, [hl]
+	ret
+
+GetBaseData::
+	push bc
+	push de
+	push hl
+	ldh a, [hROMBank]
+	push af
+	ld a, BANK(BaseData)
+	rst Bankswitch
+
+; Egg doesn't have BaseData
+	ld a, [wCurSpecies]
+	cp EGG
+	jr z, .egg
+
+; Get BaseData
+	dec a
+	ld bc, BASE_DATA_SIZE
+	ld hl, BaseData
+	call AddNTimes
+	ld de, wCurBaseData
+	ld bc, BASE_DATA_SIZE
+	call CopyBytes
+	jr .end
+
+.egg
+	ld de, UnknownEggPic
+
+; Sprite dimensions
+	ld b, $55 ; 5x5
+	ld hl, wBasePicSize
+	ld [hl], b
+
+; Beta front and back sprites
+; (see pokegold-spaceworld's data/pokemon/base_stats/*)
+	ld hl, wBaseUnusedFrontpic
+	ld [hl], e
+	inc hl
+	ld [hl], d
+	inc hl
+	ld [hl], e
+	inc hl
+	ld [hl], d
+	jr .end ; useless
+
+.end
+; Replace Pokedex # with species
+	ld a, [wCurSpecies]
+	ld [wBaseDexNo], a
+
+	pop af
+	rst Bankswitch
+	pop hl
+	pop de
+	pop bc
+	ret
+
+GetCurNick::
+	ld a, [wCurPartyMon]
+	ld hl, wPartyMonNicknames
+
+GetNick::
+; Get nickname a from list hl.
+
+	push hl
+	push bc
+
+	call SkipNames
+	ld de, wStringBuffer1
+
+	push de
+	ld bc, MON_NAME_LENGTH
+	call CopyBytes
+	pop de
+
+	callfar CorrectNickErrors
+
+	pop bc
+	pop hl
+	ret
+\ No newline at end of file