Import newlib and create makefile

1 files changed, 64 insertions, 0 deletions

diff --git a/newlib/configure.in b/newlib/configure.in
new file mode 100644
index 0000000..218e69e
--- /dev/null
+++ b/newlib/configure.in
@@ -0,0 +1,64 @@
+dnl This is the newlib configure.in file.
+dnl Process this file with autoconf to produce a configure script.
+
+AC_PREREQ(2.5)
+AC_INIT(libc)
+
+dnl Can't be done in NEWLIB_CONFIGURE because that confuses automake. 
+AC_CONFIG_AUX_DIR(..)
+
+NEWLIB_CONFIGURE(.)
+
+configdirs="libc libm"
+
+AC_ARG_ENABLE(newlib_hw_fp,
+[  --enable-newlib-hw-fp    Turn on hardware floating point math],
+[case "${enableval}" in
+   yes) newlib_hw_fp=true ;;
+   no)  newlib_hw_fp=false ;;
+   *) AC_MSG_ERROR(bad value ${enableval} for --enable-newlib-hw-fp) ;;
+ esac],[newlib_hw_fp=false])
+AM_CONDITIONAL(NEWLIB_HW_FP, test x$newlib_hw_fp = xtrue)
+
+if test -z "${with_multisubdir}"; then
+  configdirs="${configdirs} doc"
+  have_doc=yes
+else
+  have_doc=
+fi
+AM_CONDITIONAL(HAVE_DOC, test x$have_doc = xyes)
+
+AC_CONFIG_SUBDIRS(${configdirs})
+
+CRT0=
+CRT0_DIR=
+if test -n "${sys_dir}"; then
+  CRT0=crt0.o
+  CRT0_DIR=libc
+fi
+AC_SUBST(CRT0)
+AC_SUBST(CRT0_DIR)
+
+
+
+
+if test "${multilib}" = "yes"; then
+  multilib_arg="--enable-multilib"
+else
+  multilib_arg=
+fi
+
+
+AC_OUTPUT(Makefile,
+[if test -n "$CONFIG_FILES"; then
+  . ${newlib_basedir}/../config-ml.in
+fi],
+srcdir=${srcdir}
+host=${host}
+target=${target}
+with_multisubdir=${with_multisubdir}
+ac_configure_args="${multilib_arg} ${ac_configure_args}"
+CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
+newlib_basedir=${newlib_basedir}
+CC="${CC}"
+)