1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
|
_BugContestJudging:
call ContestScore
farcall StubbedTrainerRankings_BugContestScore
call BugContest_JudgeContestants
ld a, [wBugContestThirdPlaceWinnerID]
call LoadContestantName
ld a, [wBugContestThirdPlaceMon]
ld [wNamedObjectIndex], a
call GetPokemonName
ld hl, ContestJudging_ThirdPlaceText
call PrintText
ld a, [wBugContestSecondPlaceWinnerID]
call LoadContestantName
ld a, [wBugContestSecondPlaceMon]
ld [wNamedObjectIndex], a
call GetPokemonName
ld hl, ContestJudging_SecondPlaceText
call PrintText
ld a, [wBugContestFirstPlaceWinnerID]
call LoadContestantName
ld a, [wBugContestFirstPlaceMon]
ld [wNamedObjectIndex], a
call GetPokemonName
ld hl, ContestJudging_FirstPlaceText
call PrintText
jp BugContest_GetPlayersResult
ContestJudging_FirstPlaceText:
text_far _ContestJudging_FirstPlaceText
text_asm
ld de, SFX_1ST_PLACE
call PlaySFX
call WaitSFX
ld hl, ContestJudging_FirstPlaceScoreText
ret
ContestJudging_FirstPlaceScoreText:
text_far _ContestJudging_FirstPlaceScoreText
text_end
ContestJudging_SecondPlaceText:
; Placing second was @ , who caught a @ !@ @
text_far _ContestJudging_SecondPlaceText
text_asm
ld de, SFX_2ND_PLACE
call PlaySFX
call WaitSFX
ld hl, ContestJudging_SecondPlaceScoreText
ret
ContestJudging_SecondPlaceScoreText:
text_far _ContestJudging_SecondPlaceScoreText
text_end
ContestJudging_ThirdPlaceText:
; Placing third was @ , who caught a @ !@ @
text_far _ContestJudging_ThirdPlaceText
text_asm
ld de, SFX_3RD_PLACE
call PlaySFX
call WaitSFX
ld hl, ContestJudging_ThirdPlaceScoreText
ret
ContestJudging_ThirdPlaceScoreText:
text_far _ContestJudging_ThirdPlaceScoreText
text_end
LoadContestantName:
; If a = 1, get your name.
assert BUG_CONTEST_PLAYER == 1
dec a
jr z, .player
; Find the pointer for the trainer class of the Bug Catching Contestant whose ID is in a.
ld c, a
ld b, 0
ld hl, BugContestantPointers
add hl, bc
add hl, bc
ld a, [hli]
ld h, [hl]
ld l, a
; Copy the Trainer Class to c.
ld a, [hli]
ld c, a
; Save hl and bc for later.
push hl
push bc
; Get the Trainer Class name and copy it into wBugContestWinnerName.
callfar GetTrainerClassName
ld hl, wStringBuffer1
ld de, wBugContestWinnerName
ld bc, TRAINER_CLASS_NAME_LENGTH
call CopyBytes
ld hl, wBugContestWinnerName
; Delete the trailing terminator and replace it with a space.
.next
ld a, [hli]
cp "@"
jr nz, .next
dec hl
ld [hl], " "
inc hl
ld d, h
ld e, l
; Restore the Trainer Class ID and Trainer ID pointer. Save de for later.
pop bc
pop hl
push de
; Get the name of the trainer with class c and ID b.
ld a, [hl]
ld b, a
callfar GetTrainerName
; Append the name to wBugContestWinnerName.
ld hl, wStringBuffer1
pop de
ld bc, NAME_LENGTH - 1
jp CopyBytes
.player
ld hl, wPlayerName
ld de, wBugContestWinnerName
ld bc, NAME_LENGTH
jp CopyBytes
INCLUDE "data/events/bug_contest_winners.asm"
BugContest_GetPlayersResult:
ld hl, wBugContestThirdPlaceWinnerID
ld de, -BUG_CONTESTANT_SIZE
ld b, 3 ; 3rd, 2nd, or 1st
.loop
ld a, [hl]
cp BUG_CONTEST_PLAYER
jr z, .done
add hl, de
dec b
jr nz, .loop
.done
ret
BugContest_JudgeContestants:
call ClearContestResults
call ComputeAIContestantScores
ld hl, wBugContestTempWinnerID
ld a, BUG_CONTEST_PLAYER
ld [hli], a
ld a, [wContestMon]
ld [hli], a
ldh a, [hProduct]
ld [hli], a
ldh a, [hProduct + 1]
ld [hl], a
call DetermineContestWinners
ret
ClearContestResults:
ld hl, wBugContestResults
ld b, wBugContestWinnersEnd - wBugContestResults
xor a
.loop
ld [hli], a
dec b
jr nz, .loop
ret
DetermineContestWinners:
ld de, wBugContestTempScore
ld hl, wBugContestFirstPlaceScore
ld c, 2
call CompareBytes
jr c, .not_first_place
ld hl, wBugContestSecondPlaceWinnerID
ld de, wBugContestThirdPlaceWinnerID
ld bc, BUG_CONTESTANT_SIZE
call CopyBytes
ld hl, wBugContestFirstPlaceWinnerID
ld de, wBugContestSecondPlaceWinnerID
ld bc, BUG_CONTESTANT_SIZE
call CopyBytes
ld hl, wBugContestFirstPlaceWinnerID
call CopyTempContestant
jr .done
.not_first_place
ld de, wBugContestTempScore
ld hl, wBugContestSecondPlaceScore
ld c, 2
call CompareBytes
jr c, .not_second_place
ld hl, wBugContestSecondPlaceWinnerID
ld de, wBugContestThirdPlaceWinnerID
ld bc, BUG_CONTESTANT_SIZE
call CopyBytes
ld hl, wBugContestSecondPlaceWinnerID
call CopyTempContestant
jr .done
.not_second_place
ld de, wBugContestTempScore
ld hl, wBugContestThirdPlaceScore
ld c, 2
call CompareBytes
jr c, .done
ld hl, wBugContestThirdPlaceWinnerID
call CopyTempContestant
.done
ret
CopyTempContestant:
; Could've just called CopyBytes.
ld de, wBugContestTempWinnerID
rept BUG_CONTESTANT_SIZE - 1
ld a, [de]
inc de
ld [hli], a
endr
ld a, [de]
inc de
ld [hl], a
ret
ComputeAIContestantScores:
ld e, 0
.loop
push de
call CheckBugContestContestantFlag
pop de
jr nz, .done
ld a, e
inc a
inc a
ld [wBugContestTempWinnerID], a
dec a
ld c, a
ld b, 0
ld hl, BugContestantPointers
add hl, bc
add hl, bc
ld a, [hli]
ld h, [hl]
ld l, a
inc hl
inc hl
.loop2
; 0, 1, or 2 for 1st, 2nd, or 3rd
call Random
and 3
cp 3
jr z, .loop2
ld c, a
ld b, 0
add hl, bc
add hl, bc
add hl, bc
ld a, [hli]
ld [wBugContestTempMon], a
ld a, [hli]
ld h, [hl]
ld l, a
; randomly perturb score
call Random
and %111
ld c, a
ld b, 0
add hl, bc
ld a, h
ld [wBugContestTempScore], a
ld a, l
ld [wBugContestTempScore + 1], a
push de
call DetermineContestWinners
pop de
.done
inc e
ld a, e
cp NUM_BUG_CONTESTANTS
jr nz, .loop
ret
ContestScore:
; Determine the player's score in the Bug Catching Contest.
xor a
ldh [hProduct], a
ldh [hMultiplicand], a
ld a, [wContestMonSpecies] ; Species
and a
jr z, .done
; Tally the following:
; Max HP * 4
ld a, [wContestMonMaxHP + 1]
call .AddContestStat
ld a, [wContestMonMaxHP + 1]
call .AddContestStat
ld a, [wContestMonMaxHP + 1]
call .AddContestStat
ld a, [wContestMonMaxHP + 1]
call .AddContestStat
; Stats
ld a, [wContestMonAttack + 1]
call .AddContestStat
ld a, [wContestMonDefense + 1]
call .AddContestStat
ld a, [wContestMonSpeed + 1]
call .AddContestStat
ld a, [wContestMonSpclAtk + 1]
call .AddContestStat
ld a, [wContestMonSpclDef + 1]
call .AddContestStat
; DVs
ld a, [wContestMonDVs + 0]
ld b, a
and %0010
add a
add a
ld c, a
swap b
ld a, b
and %0010
add a
add c
ld d, a
ld a, [wContestMonDVs + 1]
ld b, a
and %0010
ld c, a
swap b
ld a, b
and %0010
srl a
add c
add c
add d
add d
call .AddContestStat
; Remaining HP / 8
ld a, [wContestMonHP + 1]
srl a
srl a
srl a
call .AddContestStat
; Whether it's holding an item
ld a, [wContestMonItem]
and a
jr z, .done
ld a, 1
call .AddContestStat
.done
ret
.AddContestStat:
ld hl, hMultiplicand
add [hl]
ld [hl], a
ret nc
dec hl
inc [hl]
ret
|
