1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
|
UserPartyAttr::
push af
ld a, [hBattleTurn]
and a
jr nz, .ot
pop af
jr BattlePartyAttr
.ot
pop af
jr OTPartyAttr
OpponentPartyAttr::
push af
ld a, [hBattleTurn]
and a
jr z, .ot
pop af
jr BattlePartyAttr
.ot
pop af
jr OTPartyAttr
BattlePartyAttr::
; Get attribute a from the party struct of the active battle mon.
push bc
ld c, a
ld b, 0
ld hl, wPartyMons
add hl, bc
ld a, [wCurBattleMon]
call GetPartyLocation
pop bc
ret
OTPartyAttr::
; Get attribute a from the party struct of the active enemy mon.
push bc
ld c, a
ld b, 0
ld hl, wOTPartyMon1Species
add hl, bc
ld a, [wCurOTMon]
call GetPartyLocation
pop bc
ret
ResetDamage::
xor a
ld [wCurDamage], a
ld [wCurDamage + 1], a
ret
SetPlayerTurn::
xor a
ld [hBattleTurn], a
ret
SetEnemyTurn::
ld a, 1
ld [hBattleTurn], a
ret
UpdateOpponentInParty::
ld a, [hBattleTurn]
and a
jr z, UpdateEnemyMonInParty
jr UpdateBattleMonInParty
UpdateUserInParty::
ld a, [hBattleTurn]
and a
jr z, UpdateBattleMonInParty
jr UpdateEnemyMonInParty
UpdateBattleMonInParty::
; Update level, status, current HP
ld a, [wCurBattleMon]
UpdateBattleMon::
ld hl, wPartyMon1Level
call GetPartyLocation
ld d, h
ld e, l
ld hl, wBattleMonLevel
ld bc, wBattleMonMaxHP - wBattleMonLevel
jp CopyBytes
UpdateEnemyMonInParty::
; Update level, status, current HP
; No wildmons.
ld a, [wBattleMode]
dec a
ret z
ld a, [wCurOTMon]
ld hl, wOTPartyMon1Level
call GetPartyLocation
ld d, h
ld e, l
ld hl, wEnemyMonLevel
ld bc, wEnemyMonMaxHP - wEnemyMonLevel
jp CopyBytes
RefreshBattleHuds::
call UpdateBattleHuds
ld c, 3
call DelayFrames
jp WaitBGMap
UpdateBattleHuds::
farcall UpdatePlayerHUD
farcall UpdateEnemyHUD
ret
INCLUDE "home/battle_vars.asm"
FarCopyRadioText::
inc hl
ld a, [hROMBank]
push af
ld a, [hli]
ld e, a
ld a, [hli]
ld d, a
ld a, [hli]
ld [hROMBank], a
ld [MBC3RomBank], a
ld a, e
ld l, a
ld a, d
ld h, a
ld de, wRadioText
ld bc, 2 * SCREEN_WIDTH
call CopyBytes
pop af
ld [hROMBank], a
ld [MBC3RomBank], a
ret
MobileTextBorder::
; For mobile link battles only.
ld a, [wLinkMode]
cp LINK_MOBILE
ret c
; Draw a cell phone icon at the
; top right corner of the border.
hlcoord 19, 12
ld [hl], $5e ; top
hlcoord 19, 13
ld [hl], $5f ; bottom
ret
BattleTextBox::
; Open a textbox and print text at hl.
push hl
call SpeechTextBox
call MobileTextBorder
call UpdateSprites
call ApplyTilemap
pop hl
call PrintTextBoxText
ret
StdBattleTextBox::
; Open a textbox and print battle text at 20:hl.
ld a, [hROMBank]
push af
ld a, BANK(BattleText)
rst Bankswitch
call BattleTextBox
pop af
rst Bankswitch
ret
GetBattleAnimPointer::
ld a, BANK(BattleAnimations)
rst Bankswitch
ld a, [hli]
ld [wBattleAnimAddress], a
ld a, [hl]
ld [wBattleAnimAddress + 1], a
ld a, BANK(BattleAnimCommands)
rst Bankswitch
ret
GetBattleAnimByte::
push hl
push de
ld hl, wBattleAnimAddress
ld e, [hl]
inc hl
ld d, [hl]
ld a, BANK(BattleAnimations)
rst Bankswitch
ld a, [de]
ld [wBattleAnimByte], a
inc de
ld a, BANK(BattleAnimCommands)
rst Bankswitch
ld [hl], d
dec hl
ld [hl], e
pop de
pop hl
ld a, [wBattleAnimByte]
ret
|
