1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
INCLUDE "constants.asm"
SECTION "home/random.asm", ROM0
Random::
; A simple hardware-based random number generator (RNG).
; Two random numbers are generated by adding and subtracting
; the divider to the respective values every time it's called.
; The divider is a register that increments at a rate of 16384Hz.
; For comparison, the Game Boy operates at a clock speed of 4.2MHz.
; This implementation also takes the current scanline as read from rLY
; and adds it nybble-swapped to the value of the divider. The unswapped
; value of rLY is also added to the value that's subtracted.
; Additionally, an equivalent function is executed in VBlank.
; This leaves a with the value in hRandomSub.
push bc
ldh a, [rLY]
ld c, a
swap a
ld b, a
ldh a, [rDIV]
adc b
ld b, a
ldh a, [hRandomAdd]
adc b
ldh [hRandomAdd], a
ldh a, [rLY]
swap a
ld b, a
ldh a, [rDIV]
adc b
adc c
ld b, a
ldh a, [hRandomSub]
sbc b
ldh [hRandomSub], a
pop bc
ret
BattleRandom::
; _BattleRandom lives in another bank.
; It handles all RNG calls in the battle engine, allowing
; link battles to remain in sync using a shared PRNG.
ldh a, [hROMBank]
push af
ld a, BANK(_BattleRandom)
call Bankswitch
call _BattleRandom
ld [wPredefHL + 1], a
pop af
call Bankswitch
ld a, [wPredefHL + 1]
ret
|
