1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
BattleCommand_Thief:
; thief
ldh a, [hBattleTurn]
and a
jr nz, .enemy
; The player needs to be able to steal an item.
call .playeritem
ld a, [hl]
and a
ret nz
; The enemy needs to have an item to steal.
call .enemyitem
ld a, [hl]
and a
ret z
; Can't steal mail.
ld [wNamedObjectIndex], a
ld d, a
farcall ItemIsMail
ret c
ld a, [wEffectFailed]
and a
ret nz
ld a, [wLinkMode]
and a
jr z, .stealenemyitem
ld a, [wBattleMode]
dec a
ret z
.stealenemyitem
call .enemyitem
xor a
ld [hl], a
ld [de], a
call .playeritem
ld a, [wNamedObjectIndex]
ld [hl], a
ld [de], a
jr .stole
.enemy
; The enemy can't already have an item.
call .enemyitem
ld a, [hl]
and a
ret nz
; The player must have an item to steal.
call .playeritem
ld a, [hl]
and a
ret z
; Can't steal mail!
ld [wNamedObjectIndex], a
ld d, a
farcall ItemIsMail
ret c
ld a, [wEffectFailed]
and a
ret nz
; If the enemy steals your item,
; it's gone for good if you don't get it back.
call .playeritem
xor a
ld [hl], a
ld [de], a
call .enemyitem
ld a, [wNamedObjectIndex]
ld [hl], a
ld [de], a
.stole
call GetItemName
ld hl, StoleText
jp StdBattleTextbox
.playeritem
ld a, MON_ITEM
call BattlePartyAttr
ld d, h
ld e, l
ld hl, wBattleMonItem
ret
.enemyitem
ld a, MON_ITEM
call OTPartyAttr
ld d, h
ld e, l
ld hl, wEnemyMonItem
ret
|
