1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
ResetGameTime::
xor a
ld [wGameTimeCap], a
ld [wGameTimeHours], a
ld [wGameTimeHours + 1], a
ld [wGameTimeMinutes], a
ld [wGameTimeSeconds], a
ld [wGameTimeFrames], a
ret
GameTimer::
nop
; Increment the game timer by one frame.
; The game timer is capped at 999:59:59.00.
; Don't update if game logic is paused.
ld a, [wGameLogicPaused]
and a
ret nz
; Is the timer paused?
ld hl, wGameTimerPaused
bit GAME_TIMER_PAUSED_F, [hl]
ret z
; Is the timer already capped?
ld hl, wGameTimeCap
bit 0, [hl]
ret nz
; +1 frame
ld hl, wGameTimeFrames
ld a, [hl]
inc a
cp 60 ; frames/second
jr nc, .second
ld [hl], a
ret
.second
xor a
ld [hl], a
; +1 second
ld hl, wGameTimeSeconds
ld a, [hl]
inc a
cp 60 ; seconds/minute
jr nc, .minute
ld [hl], a
ret
.minute
xor a
ld [hl], a
; +1 minute
ld hl, wGameTimeMinutes
ld a, [hl]
inc a
cp 60 ; minutes/hour
jr nc, .hour
ld [hl], a
ret
.hour
xor a
ld [hl], a
; +1 hour
ld a, [wGameTimeHours]
ld h, a
ld a, [wGameTimeHours + 1]
ld l, a
inc hl
; Cap the timer after 1000 hours.
ld a, h
cp HIGH(1000)
jr c, .ok
ld a, l
cp LOW(1000)
jr c, .ok
ld hl, wGameTimeCap
set 0, [hl]
ld a, 59 ; 999:59:59.00
ld [wGameTimeMinutes], a
ld [wGameTimeSeconds], a
ret
.ok
ld a, h
ld [wGameTimeHours], a
ld a, l
ld [wGameTimeHours + 1], a
ret
|
