1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
|
HandleTilts: ; 0x3582
call HandleLeftTilt
call HandleRightTilt
call HandleUpperTilt
ret
HandleLeftTilt: ; 0x358c
ld a, [wLeftTiltReset]
and a
jr nz, .tiltCoolDown
ld hl, wKeyConfigLeftTilt
call IsKeyPressed2
jr z, .tiltCoolDown
ld a, [wLeftTiltCounter]
cp 3
jr z, .startCoolDown
inc a
ld [wLeftTiltCounter], a
cp 1
jr nz, .skipSoundEffect
lb de, $00, $3f
call PlaySoundEffect
.skipSoundEffect
ld a, [wPinballIsVisible]
ld hl, wEnableBallGravityAndTilt
and [hl]
jr z, .skipBallMovement
ld a, [wBallXPos + 1]
dec a ; move ball's position to the left by 1 pixel
ld [wBallXPos + 1], a
.skipBallMovement
ld a, [wLeftAndRightTiltPixelsOffset]
inc a
ld [wLeftAndRightTiltPixelsOffset], a
ld a, 1
ld [wLeftTiltPushing], a
ret
.startCoolDown
ld a, 1
ld [wLeftTiltReset], a
.tiltCoolDown
xor a
ld [wLeftTiltPushing], a
ld a, [wLeftTiltCounter]
and a
jr z, .done
dec a
ld [wLeftTiltCounter], a
ld a, [wLeftAndRightTiltPixelsOffset]
dec a
ld [wLeftAndRightTiltPixelsOffset], a
ret
.done
ld hl, wKeyConfigLeftTilt
call IsKeyPressed2
ret nz
xor a
ld [wLeftTiltReset], a
ret
HandleRightTilt: ; 0x35f3
ld a, [wRightTiltReset]
and a
jr nz, .tiltCoolDown
ld hl, wKeyConfigRightTilt
call IsKeyPressed2
jr z, .tiltCoolDown
ld a, [wRightTiltCounter]
cp 3
jr z, .startCoolDown
inc a
ld [wRightTiltCounter], a
cp 1
jr nz, .skipSoundEffect
lb de, $00, $3f
call PlaySoundEffect
.skipSoundEffect
ld a, [wPinballIsVisible]
ld hl, wEnableBallGravityAndTilt
and [hl]
jr z, .skipBallMovement
ld a, [wBallXPos + 1]
inc a ; move ball's position to the right by 1 pixel
ld [wBallXPos + 1], a
.skipBallMovement
ld a, [wLeftAndRightTiltPixelsOffset]
dec a
ld [wLeftAndRightTiltPixelsOffset], a
ld a, 1
ld [wRightTiltPushing], a
ret
.startCoolDown
ld a, 1
ld [wRightTiltReset], a
.tiltCoolDown
xor a
ld [wRightTiltPushing], a
ld a, [wRightTiltCounter]
and a
jr z, .done
dec a
ld [wRightTiltCounter], a
ld a, [wLeftAndRightTiltPixelsOffset]
inc a
ld [wLeftAndRightTiltPixelsOffset], a
ret
.done
ld hl, wKeyConfigRightTilt
call IsKeyPressed2
ret nz
xor a
ld [wRightTiltReset], a
ret
HandleUpperTilt: ; 0x365a
ld a, [wUpperTiltReset]
and a
jr nz, .tiltCoolDown
ld hl, wKeyConfigUpperTilt
call IsKeyPressed2
jr z, .tiltCoolDown
ld a, [wUpperTiltCounter]
cp 4
jr z, .startCoolDown
inc a
ld [wUpperTiltCounter], a
cp 1
jr nz, .skipSoundEffect
lb de, $00, $3f
call PlaySoundEffect
.skipSoundEffect
ld a, [wPinballIsVisible]
ld hl, wEnableBallGravityAndTilt
and [hl]
jr z, .skipBallMovement
ld a, [wBallYPos + 1]
inc a ; move ball's position down by 1 pixel
ld [wBallYPos + 1], a
.skipBallMovement
ld a, [wUpperTiltPixelsOffset]
dec a
ld [wUpperTiltPixelsOffset], a
ld a, 1
ld [wUpperTiltPushing], a
ret
.startCoolDown
ld a, 1
ld [wUpperTiltReset], a
.tiltCoolDown
xor a
ld [wUpperTiltPushing], a
ld a, [wUpperTiltCounter]
and a
jr z, .done
dec a
ld [wUpperTiltCounter], a
ld a, [wUpperTiltPixelsOffset]
inc a
ld [wUpperTiltPixelsOffset], a
ret
.done
ld hl, wKeyConfigUpperTilt
call IsKeyPressed2
ret nz
xor a
ld [wUpperTiltReset], a
ret
ApplyTiltForces: ; 0x36c1
ld a, [wPinballIsVisible]
ld hl, wEnableBallGravityAndTilt
and [hl]
ret z
ld c, $0
ld a, [wUpperTiltPushing]
srl a
rl c
ld a, [wRightTiltPushing]
srl a
rl c
ld a, [wLeftTiltPushing]
srl a
rl c
ld b, $0
sla c
ld hl, TiltForces
add hl, bc
ld a, [hli]
ld h, [hl]
ld l, a
bit 7, h
ret nz
ld a, [wCollisionNormalAngle]
ld c, a
ld b, $0
sla c
rl b
sla c
rl b
add hl, bc
ld a, [hLoadedROMBank]
push af
ld a, BANK(TiltLeftOnlyForce)
ld [hLoadedROMBank], a
ld [MBC5RomBank], a
ld a, [wBallXVelocity]
add [hl]
ld [wBallXVelocity], a
inc hl
ld a, [wBallXVelocity + 1]
adc [hl]
ld [wBallXVelocity + 1], a
inc hl
ld a, [wBallYVelocity]
add [hl]
ld [wBallYVelocity], a
inc hl
ld a, [wBallYVelocity + 1]
adc [hl]
ld [wBallYVelocity + 1], a
pop af
ld [hLoadedROMBank], a
ld [MBC5RomBank], a
ret
TiltForces: ; 0x372d
dw $FFFF ; no tilt
dw TiltLeftOnlyForce
dw TiltRightOnlyForce
dw $FFFF ; left + right (cancel each other, so no tilt)
dw TiltUpOnlyForce
dw TiltUpLeftForce
dw TiltUpRightForce
dw TiltUpOnlyForce
|
