1 files changed, 117 insertions, 0 deletions
diff --git a/engine/events/hidden_object_functions3.asm b/engine/events/hidden_object_functions3.asm
new file mode 100755
index 00000000..1237e960
--- /dev/null
+++ b/engine/events/hidden_object_functions3.asm
@@ -0,0 +1,117 @@
+; prints text for bookshelves in buildings without sign events
+PrintBookshelfText::
+	ld a, [wSpriteStateData1 + 9] ; player's sprite facing direction
+	cp SPRITE_FACING_UP
+	jr nz, .noMatch
+; facing up
+	ld a, [wCurMapTileset]
+	ld b, a
+	aCoord 8, 7
+	ld c, a
+	ld hl, BookshelfTileIDs
+.loop
+	ld a, [hli]
+	cp $ff
+	jr z, .noMatch
+	cp b
+	jr nz, .nextBookshelfEntry1
+	ld a, [hli]
+	cp c
+	jr nz, .nextBookshelfEntry2
+	ld a, [hl]
+	push af
+	call EnableAutoTextBoxDrawing
+	pop af
+	call PrintPredefTextID
+	xor a
+	ld [$ffdb], a
+	ret
+.nextBookshelfEntry1
+	inc hl
+.nextBookshelfEntry2
+	inc hl
+	jr .loop
+.noMatch
+	ld a, $ff
+	ld [$ffdb], a
+	jpba PrintCardKeyText
+
+INCLUDE "data/bookshelf_tile_ids.asm"
+
+IndigoPlateauStatues::
+	TX_ASM
+	ld hl, IndigoPlateauStatuesText1
+	call PrintText
+	ld a, [wXCoord]
+	bit 0, a
+	ld hl, IndigoPlateauStatuesText2
+	jr nz, .ok
+	ld hl, IndigoPlateauStatuesText3
+.ok
+	call PrintText
+	jp TextScriptEnd
+
+IndigoPlateauStatuesText1:
+	TX_FAR _IndigoPlateauStatuesText1
+	db "@"
+
+IndigoPlateauStatuesText2:
+	TX_FAR _IndigoPlateauStatuesText2
+	db "@"
+
+IndigoPlateauStatuesText3:
+	TX_FAR _IndigoPlateauStatuesText3
+	db "@"
+
+BookOrSculptureText::
+	TX_ASM
+	ld hl, PokemonBooksText
+	ld a, [wCurMapTileset]
+	cp MANSION ; Celadon Mansion tileset
+	jr nz, .ok
+	aCoord 8, 6
+	cp $38
+	jr nz, .ok
+	ld hl, DiglettSculptureText
+.ok
+	call PrintText
+	jp TextScriptEnd
+
+PokemonBooksText:
+	TX_FAR _PokemonBooksText
+	db "@"
+
+DiglettSculptureText:
+	TX_FAR _DiglettSculptureText
+	db "@"
+
+ElevatorText::
+	TX_FAR _ElevatorText
+	db "@"
+
+TownMapText::
+	TX_FAR _TownMapText
+	TX_BLINK
+	TX_ASM
+	ld a, $1
+	ld [wDoNotWaitForButtonPressAfterDisplayingText], a
+	ld hl, wd730
+	set 6, [hl]
+	call GBPalWhiteOutWithDelay3
+	xor a
+	ld [hWY], a
+	inc a
+	ld [H_AUTOBGTRANSFERENABLED], a
+	call LoadFontTilePatterns
+	callba DisplayTownMap
+	ld hl, wd730
+	res 6, [hl]
+	ld de, TextScriptEnd
+	push de
+	ld a, [H_LOADEDROMBANK]
+	push af
+	jp CloseTextDisplay
+
+PokemonStuffText::
+	TX_FAR _PokemonStuffText
+	db "@"