Update to latest pokered

4 files changed, 123 insertions, 3 deletions

diff --git a/engine/menu/draw_badges.asm b/engine/menu/draw_badges.asm
new file mode 100644
index 00000000..9e6262a0
--- /dev/null
+++ b/engine/menu/draw_badges.asm
@@ -0,0 +1,120 @@
+DrawBadges:
+; Draw 4x2 gym leader faces, with the faces replaced by
+; badges if they are owned. Used in the player status screen.
+
+; In Japanese versions, names are displayed above faces.
+; Instead of removing relevant code, the name graphics were erased.
+
+; Tile ids for face/badge graphics.
+	ld de, wBadgeOrFaceTiles
+	ld hl, .FaceBadgeTiles
+	ld bc, 8
+	call CopyData
+
+; Booleans for each badge.
+	ld hl, wTempObtainedBadgesBooleans
+	ld bc, 8
+	xor a
+	call FillMemory
+
+; Alter these based on owned badges.
+	ld de, wTempObtainedBadgesBooleans
+	ld hl, wBadgeOrFaceTiles
+	ld a, [wObtainedBadges]
+	ld b, a
+	ld c, 8
+.CheckBadge
+	srl b
+	jr nc, .NextBadge
+	ld a, [hl]
+	add 4 ; Badge graphics are after each face
+	ld [hl], a
+	ld a, 1
+	ld [de], a
+.NextBadge
+	inc hl
+	inc de
+	dec c
+	jr nz, .CheckBadge
+
+; Draw two rows of badges.
+	ld hl, wBadgeNumberTile
+	ld a, $d8 ; [1]
+	ld [hli], a
+	ld [hl], $60 ; First name
+
+	coord hl, 2, 11
+	ld de, wTempObtainedBadgesBooleans
+	call .DrawBadgeRow
+
+	coord hl, 2, 14
+	ld de, wTempObtainedBadgesBooleans + 4
+;	call .DrawBadgeRow
+;	ret
+
+.DrawBadgeRow
+; Draw 4 badges.
+
+	ld c, 4
+.DrawBadge
+	push de
+	push hl
+
+; Badge no.
+	ld a, [wBadgeNumberTile]
+	ld [hli], a
+	inc a
+	ld [wBadgeNumberTile], a
+
+; Names aren't printed if the badge is owned.
+	ld a, [de]
+	and a
+	ld a, [wBadgeNameTile]
+	jr nz, .SkipName
+	call .PlaceTiles
+	jr .PlaceBadge
+
+.SkipName
+	inc a
+	inc a
+	inc hl
+
+.PlaceBadge
+	ld [wBadgeNameTile], a
+	ld de, SCREEN_WIDTH - 1
+	add hl, de
+	ld a, [wBadgeOrFaceTiles]
+	call .PlaceTiles
+	add hl, de
+	call .PlaceTiles
+
+; Shift badge array back one byte.
+	push bc
+	ld hl, wBadgeOrFaceTiles + 1
+	ld de, wBadgeOrFaceTiles
+	ld bc, 8
+	call CopyData
+	pop bc
+
+	pop hl
+	ld de, 4
+	add hl, de
+
+	pop de
+	inc de
+	dec c
+	jr nz, .DrawBadge
+	ret
+
+.PlaceTiles
+	ld [hli], a
+	inc a
+	ld [hl], a
+	inc a
+	ret
+
+.FaceBadgeTiles
+	db $20, $28, $30, $38, $40, $48, $50, $58
+
+GymLeaderFaceAndBadgeTileGraphics:
+	INCBIN "gfx/badges.2bpp"
diff --git a/engine/menu/draw_start_menu.asm b/engine/menu/draw_start_menu.asm
index 86e68733..914284c4 100644
--- a/engine/menu/draw_start_menu.asm
+++ b/engine/menu/draw_start_menu.asm
@@ -27,7 +27,7 @@ DrawStartMenu:
 	set 6,[hl] ; no pauses between printing each letter
 	coord hl, 12, 2
 	CheckEvent EVENT_GOT_POKEDEX
-; case for not having pokdex
+; case for not having pokedex
 	ld a,$06
 	jr z,.storeMenuItemCount
 ; case for having pokedex
diff --git a/engine/menu/naming_screen.asm b/engine/menu/naming_screen.asm
index 7835be97..58bfc0d7 100755
--- a/engine/menu/naming_screen.asm
+++ b/engine/menu/naming_screen.asm
@@ -412,7 +412,7 @@ PrintNicknameAndUnderscores:
 	call EraseMenuCursor
 	ld a, $11 ; "ED" x coord
 	ld [wTopMenuItemX], a
-	ld a, $5 ; "ED" y corrd
+	ld a, $5 ; "ED" y coord
 	ld [wCurrentMenuItem], a
 	ld a, [wNamingScreenType]
 	cp NAME_MON_SCREEN
diff --git a/engine/menu/pokedex.asm b/engine/menu/pokedex.asm
index e3f9f1dd..2b66cda1 100755
--- a/engine/menu/pokedex.asm
+++ b/engine/menu/pokedex.asm
@@ -648,7 +648,7 @@ PokedexToIndex:
 	ret
 
 IndexToPokedex:
-	; converts the indexédex number at wd11e to a Pokédex number
+	; converts the index number at wd11e to a Pokédex number
 	push bc
 	push hl
 	ld a,[wd11e]