1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
|
AnimateHallOfFame: ; 701a0 (1c:41a0)
call HoFFadeOutScreenAndMusic
call ClearScreen
ld c, 100
call DelayFrames
call LoadFontTilePatterns
call LoadTextBoxTilePatterns
call DisableLCD
ld hl,vBGMap0
ld bc, $800
ld a, " "
call FillMemory
call EnableLCD
ld hl, rLCDC
set 3, [hl]
xor a
ld hl, wHallOfFame
ld bc, HOF_TEAM
call FillMemory
xor a
ld [wUpdateSpritesEnabled], a
ld [hTilesetType], a
ld [W_SPRITEFLIPPED], a
ld [wLetterPrintingDelayFlags], a ; no delay
ld [wHoFMonOrPlayer], a ; mon
inc a
ld [H_AUTOBGTRANSFERENABLED], a
ld hl, wNumHoFTeams
ld a, [hl]
inc a
jr z, .skipInc ; don't wrap around to 0
inc [hl]
.skipInc
ld a, $90
ld [hWY], a
ld c, BANK(Music_HallOfFame)
ld a, MUSIC_HALL_OF_FAME
call PlayMusic
ld hl, wPartySpecies
ld c, $ff
.partyMonLoop
ld a, [hli]
cp $ff
jr z, .doneShowingParty
inc c
push hl
push bc
ld [wHoFMonSpecies], a
ld a, c
ld [wHoFPartyMonIndex], a
ld hl, wPartyMon1Level
ld bc, wPartyMon2 - wPartyMon1
call AddNTimes
ld a, [hl]
ld [wHoFMonLevel], a
call HoFShowMonOrPlayer
call HoFDisplayAndRecordMonInfo
ld c, 80
call DelayFrames
coord hl, 2, 13
ld b, $3
ld c, $e
call TextBoxBorder
coord hl, 4, 15
ld de, HallOfFameText
call PlaceString
ld c, 180
call DelayFrames
call GBFadeOutToWhite
pop bc
pop hl
jr .partyMonLoop
.doneShowingParty
ld a, c
inc a
ld hl, wHallOfFame
ld bc, HOF_MON
call AddNTimes
ld [hl], $ff
call SaveHallOfFameTeams
xor a
ld [wHoFMonSpecies], a
inc a
ld [wHoFMonOrPlayer], a ; player
call HoFShowMonOrPlayer
call HoFDisplayPlayerStats
call HoFFadeOutScreenAndMusic
xor a
ld [hWY], a
ld hl, rLCDC
res 3, [hl]
ret
HallOfFameText: ; 7026b (1c:426b)
db "HALL OF FAME@"
HoFShowMonOrPlayer: ; 70278 (1c:4278)
call ClearScreen
ld a, $d0
ld [hSCY], a
ld a, $c0
ld [hSCX], a
ld a, [wHoFMonSpecies]
ld [wcf91], a
ld [wd0b5], a
ld [wBattleMonSpecies2], a
ld [wcf1d], a
ld a, [wHoFMonOrPlayer]
and a
jr z, .showMon
; show player
call HoFLoadPlayerPics
jr .next1
.showMon
coord hl, 12, 5
call GetMonHeader
call LoadFrontSpriteByMonIndex
predef LoadMonBackPic
.next1
ld b, $b
ld c, $0
call GoPAL_SET
ld a, %11100100
ld [rBGP], a
ld c, $31 ; back pic
call HoFLoadMonPlayerPicTileIDs
ld d, $a0
ld e, 4
ld a, [wOnSGB]
and a
jr z, .next2
sla e ; scroll more slowly on SGB
.next2
call .ScrollPic ; scroll back pic left
xor a
ld [hSCY], a
ld c, a ; front pic
call HoFLoadMonPlayerPicTileIDs
ld d, 0
ld e, -4
; scroll front pic right
.ScrollPic
call DelayFrame
ld a, [hSCX]
add e
ld [hSCX], a
cp d
jr nz, .ScrollPic
ret
HoFDisplayAndRecordMonInfo: ; 702e1 (1c:42e1)
ld a, [wHoFPartyMonIndex]
ld hl, wPartyMonNicks
call GetPartyMonName
call HoFDisplayMonInfo
jp HoFRecordMonInfo
HoFDisplayMonInfo: ; 702f0 (1c:42f0)
coord hl, 0, 2
ld b, 9
ld c, 10
call TextBoxBorder
coord hl, 2, 6
ld de, HoFMonInfoText
call PlaceString
coord hl, 1, 4
ld de, wcd6d
call PlaceString
ld a, [wHoFMonLevel]
coord hl, 8, 7
call PrintLevelCommon
ld a, [wHoFMonSpecies]
ld [wd0b5], a
coord hl, 3, 9
predef PrintMonType
ld a, [wHoFMonSpecies]
jp PlayCry
HoFMonInfoText: ; 70329 (1c:4329)
db "LEVEL/"
next "TYPE1/"
next "TYPE2/@"
HoFLoadPlayerPics: ; 7033e (1c:433e)
ld de, RedPicFront
ld a, BANK(RedPicFront)
call UncompressSpriteFromDE
ld hl, S_SPRITEBUFFER1
ld de, S_SPRITEBUFFER0
ld bc, $310
call CopyData
ld de, vFrontPic
call InterlaceMergeSpriteBuffers
ld de, RedPicBack
ld a, BANK(RedPicBack)
call UncompressSpriteFromDE
predef ScaleSpriteByTwo
ld de, vBackPic
call InterlaceMergeSpriteBuffers
ld c, $1
HoFLoadMonPlayerPicTileIDs: ; 7036d (1c:436d)
; c = base tile ID
ld b, 0
coord hl, 12, 5
predef_jump CopyTileIDsFromList
HoFDisplayPlayerStats: ; 70377 (1c:4377)
SetEvent EVENT_HALL_OF_FAME_DEX_RATING
predef DisplayDexRating
coord hl, 0, 4
ld b, $6
ld c, $a
call TextBoxBorder
coord hl, 5, 0
ld b, $2
ld c, $9
call TextBoxBorder
coord hl, 7, 2
ld de, wPlayerName
call PlaceString
coord hl, 1, 6
ld de, HoFPlayTimeText
call PlaceString
coord hl, 5, 7
ld de, W_PLAYTIMEHOURS + 1
lb bc, 1, 3
call PrintNumber
ld [hl], $6d
inc hl
ld de, W_PLAYTIMEMINUTES + 1
lb bc, LEADING_ZEROES | 1, 2
call PrintNumber
coord hl, 1, 9
ld de, HoFMoneyText
call PlaceString
coord hl, 4, 10
ld de, wPlayerMoney
ld c, $a3
call PrintBCDNumber
ld hl, DexSeenOwnedText
call HoFPrintTextAndDelay
ld hl, DexRatingText
call HoFPrintTextAndDelay
ld hl, wcc5d
HoFPrintTextAndDelay: ; 703e2 (1c:43e2)
call PrintText
ld c, 120
jp DelayFrames
HoFPlayTimeText: ; 703ea (1c:43ea)
db "PLAY TIME@"
HoFMoneyText: ; 703f4 (1c:43f4)
db "MONEY@"
DexSeenOwnedText: ; 703fa (1c:43fa)
TX_FAR _DexSeenOwnedText
db "@"
DexRatingText: ; 703ff (1c:43ff)
TX_FAR _DexRatingText
db "@"
HoFRecordMonInfo: ; 70404 (1c:4404)
ld hl, wHallOfFame
ld bc, HOF_MON
ld a, [wHoFPartyMonIndex]
call AddNTimes
ld a, [wHoFMonSpecies]
ld [hli], a
ld a, [wHoFMonLevel]
ld [hli], a
ld e, l
ld d, h
ld hl, wcd6d
ld bc, $b
jp CopyData
HoFFadeOutScreenAndMusic: ; 70423 (1c:4423)
ld a, 10
ld [wAudioFadeOutCounterReloadValue], a
ld [wAudioFadeOutCounter], a
ld a, $ff
ld [wAudioFadeOutControl], a
jp GBFadeOutToWhite
|
